Imagem:Parabolic orbit.gif

Origem: Wikipédia, a enciclopédia livre.

Imagem
Histórico
Ligações

Resolução maior não disponível.

Parabolic_orbit.gif‎ (300 × 300 pixel, tamanho do ficheiro: 11 KB, tipo MIME: image/gif)

Este arquivo foi carregado no Wikimedia Commons, um acervo de conteúdo livre da Fundação Wikimedia. Veja a página descritiva da imagem para informações sobre a licença.

r_p	Periapsis' Radius

[edit] Summary

Description	Animation showing the motion of a small body (green) in a parabolic orbit around a much more massive body (blue).
Source	Own work. Rendered with PovRay-3.0, animated with gifsicle.
Date	Created 7. Mar. 2006.
Author	Brandir
Permission	Brandir put it under the GFCL and the CC-BY-SA
Other versions	None.

[edit] Licensing

I, the author of this work, hereby publish it under the following licenses:

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License".

English: This file is licensed under the Creative Commons "Attribution-ShareAlike 2.5 Spain" Licence

Español: Este fichero está bajo las condiciones de uso de la licencia de Creative Commons «Reconocimiento-CompartirIgual 2.5 España»

Català: Aquest fitxer és sota els termes d'ús la llicència de Creative Commons «Reconeixement-CompartirIgual 2.5 Espanya»

Euskara: Fitxategi hau Creative Commons-en lizentziaren erabilpen baldintzapean dago «Aitortu-PartekatuBerdin 2.5 Espainia»

Galego: Este ficheiro está baixo os termos do uso da licenza de Creative Commons «Recoñecemento-CompartirIgual 2.5 España»

You may select the license of your choice.

[edit] POV-Ray Scene description

POV-ray image description:

/*
--------------------------
Parabolic Orbit Animation
--------------------------
Created 7 Mar. 2006
*/
#include "colors.inc"

//Orbit Definition
#declare OrbitRp=6.356*1.8;

//Scene Constants
#declare EarthRadius=6.356;
#declare SatRadius=1.2;
#declare OrbitWidth=0.5;
#declare LineWidth=0.5/3;
#declare Crosslength=1.5;
#declare Textscale=9;
#declare TextColor=rgb<0,0,0>;
#declare xinit=-100;

//Variables
#declare Minit=2*OrbitRp*sqrt(2*OrbitRp-xinit)+pow(sqrt(2*OrbitRp-xinit),3)/3;
#declare M=Minit-2*clock*Minit;
#declare PI=3.14159265359;

//Anomaly Determination - Solves the equation M=2*OrbitRp*D+D^3/3
#declare p=6*OrbitRp;
#declare q=-3*M;
#declare A1=q/2+sqrt(pow(q,2)/4+pow(p,3)/27);
#if (A1>0)
    #declare U=pow(A1,1/3);
#else
    #declare U=-pow(-A1,1/3);
#end
#declare Anomaly=p/(3*U)-U;

//General settings
global_settings{
    ambient_light 1
}

light_source { <-50, 0, -70> color White }

camera {
  orthographic
  location <0, 0, -10>
  look_at  <0, 0,  0>
  up <0,100,0>
  right <100,0,0>
}

plane { <0, 0, 1>, 8
    pigment {White}
    finish{ambient 1 brilliance 0}
}


//Earth
sphere {
    <0, 0, 0>, EarthRadius
    pigment { Blue }
    finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
}


//Orbit
intersection{
    box{
        <-100,-100,-OrbitWidth>, <100,100,OrbitWidth> 
    }
    quadric{
        <0,1/(4*OrbitRp),0>,<0,0,0>,<-1,0,0>,-OrbitRp
        translate -x*OrbitWidth/2
    }
    quadric{
        <0,-1/(4*OrbitRp),0>,<0,0,0>,<1,0,0>,OrbitRp
        translate x*OrbitWidth/2
    }
    pigment{ rgb<0.8,0,0> }
    finish{ ambient 1 brilliance 0 diffuse 0}
    rotate 2.2*y
    no_shadow
}


//Satellite
sphere {
    <0, 0, -10>, SatRadius
    pigment { SeaGreen }
    finish{ ambient 1 brilliance 0 diffuse 0}
    no_shadow
    translate <-(OrbitRp-Anomaly*Anomaly/2),sqrt(2*OrbitRp)*Anomaly,0>
}

//Lines
#declare crossBars=
object{
    union{
        box{
            <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
        }
        box{
            <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
        }
        rotate z*45
        pigment{ TextColor }
        finish{ ambient 1 brilliance 0 diffuse 0}
        no_shadow
    }
}

box{
    <-OrbitRp,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7> 
    pigment{ TextColor }
    finish{ ambient 1 brilliance 0 diffuse 0}
    no_shadow
}


object{
    crossBars
}

object{
    crossBars
    translate -x*OrbitRp
}


//Text
union{
    text {
        ttf "timesi.ttf" "r" 1, 0
    }
    text {
        ttf "timesi.ttf" "p" 1, 0
        scale 0.5
        translate 0.2*x
    }
    pigment{ TextColor }
    finish{ ambient 1 brilliance 0 diffuse 0}
    scale Textscale
    translate <-(EarthRadius+0.3*(OrbitRp-EarthRadius))-Textscale/4,Textscale/4,-7>
    no_shadow
}

Ligações

As seguintes páginas apontam para este ficheiro:

Órbita

Retirado de "http://pt.wikipedia.org../../../p/a/r/Imagem%7EParabolic_orbit.gif_76f1.html"

Imagem:Parabolic orbit.gif

Origem: Wikipédia, a enciclopédia livre.

[edit] Summary

[edit] Licensing

[edit] POV-Ray Scene description

Ligações

Views

Navegação

colaboração

Busca