Soubor:KUGSPI-9 Loxodrome.gif
Z Wikipedie, otevřené encyklopedie
Větší rozlišení není k dispozici
KUGSPI-9_Loxodrome.gif (rozměr: 200 × 200 pixelů • velikost souboru: 59 kB • MIME typ: image/gif)
| Tento soubor pochází z Wikimedia Commons. Můžete se podívat na jeho tamější stránku s popisem. |
Loxodrome
- Description:
- The Loxodrome hat im Gegensatz zur archimedischen
- Kugelspirale einen konstanten Winkel zwischen
- den Längengraden und den Breitengraden, der hier
- das Verhältnis von 10 Länge zu 1 Breite hat.
- Source:
- Drawn on 26. April 2005
- with GW-BASIC (german wiki)-Programm:
100 SCREEN 1:KEY OFF:P=ATN(1)/45:R=96
110 REM P=WINKEL UMRECHNEN IN RAD:R=RADIUS DER KUGEL
120 REM (REM=REMARK=ANMERKUNG) ZWANZIG BLICKWINKEL ERZEUGEN
130 FOR U= 0 TO 175 STEP 9:T=P*U:G=COS(T):H=SIN(T)
140 CLS:LINE(60,0)-(259,199),3,B:LOCATE 2,9:PRINT RIGHT$(" "+STR$(U),3);
150 REM BREITENKREISE IN ROT ERZEUGEN
160 FOR V=90 TO 270 STEP 18:A=P*V:C=R*COS(A):Z=R*SIN(A)
170 FOR W= 0 TO 360 STEP (-2*R)/(C-.001):B=P*W
180 X= C*COS(B):Y= C*SIN(B):M=160+X:N=100-G*Z-H*Y:O=H*Z-G*Y
190 IF O>-1 THEN PSET(M,N),2
200 NEXT W:NEXT V
210 REM MERIDIANE IN GRUEN ERZEUGEN
220 FOR V=90 TO 260 STEP 18:A=P*V:E=COS(A):F=SIN(A)
230 FOR W= 0 TO 360 STEP 2:B=P*W:Z=R*SIN(B)
240 X=E*R*COS(B):Y=F*R*COS(B):M=160+X:N=100-G*Z-H*Y:O=H*Z-G*Y
250 IF O>-1 THEN PSET(M,N),1
260 NEXT W:NEXT V :V=90.1:REM STARTBREITENWINKEL
270 REM LOXODROME IN WEISS ERZEUGEN
280 FOR W= 0 TO 9000 STEP .1:B=P*W:V=V+.1*.1*ABS(COS(P*V)):A=P*V:C=R*COS(A):Z=R*SIN(A)
290 REM ABS(COS(P*V)) WEIL KLEINER RADIUS = KLEINE STRECKE
300 X= C*COS(B):Y= C*SIN(B):M=160+X:N=100-G*Z-H*Y:O=H*Z-G*Y
310 IF O>-1 THEN PSET(M,N),3
320 NEXT W
330 REM NAECHSTER BLICKWINKEL
340 IF INKEY$="" THEN 340
350 NEXT U:SCREEN 0:CLS:KEY OFF:WIDTH 80:LIST:END
360 REM SAVE"KUGSPI-9.BAS",A
- Drawn/Programmed by:
- German Wikipedia User Karl Bednarik
- made smaller with Microsoft Paint to 50%
- animated with Microsoft Gif-Animator
- Other Versions:
- none
- Copyright Status:
- Externe Links:
Odkazy k souboru
Na soubor odkazují tyto stránky:
