Bild:Bohr-sommerf.png

aus Wikipedia, der freien Enzyklopädie

Du hast neue Nachrichten auf deiner Diskussionsseite.

Bild
Dateiversionen
Dateiverweise

Keine höhere Auflösung vorhanden.

Bohr-sommerf.png‎ (720 × 450 Pixel, Dateigröße: 8 KB, MIME-Typ: image/png)

[Bearbeiten] Beschreibung, Quelle

Elektronenbahnen im Bohr-Sommerfeldschen Atommodell.

Bild wurde mit folgendem selbstgeschriebenen Programm erstellt.

# *************************************************************************
# *
# * ellipsen.gplot
# *
# * Programm zum Zeichnen von Elektronenbahnen 
# * des Bohr-Sommerfeldschen-Atommodells 
# * für ein Wasserstoffatom
# * Ausgeführt mit gnuplot 4.0 
# *************************************************************************
# Naturkonstanten:
#   h:     Plancksches Wirkungsquantum
#   h_:    h-quer (Plancksches Wirkungsquantum / (2 * PI))
#   e0:    Elementarladung (Ladung eines Elektrons)
#   me:    Masse eines Elektrons
#   eps0:  Dielektrizitätskonstante
# Abgeleitete Werte:
#   mr:    Reduzierte Masse eines Elektrons im Wasserstoffatom
#   G:     Stärke des Coulompotentials
# Hilfsvariable:
#   h_2, K
# Funktionen:
#   enrg(n) :    Energie zum Energieniveau mit der Hauptquantenzahl n
#   l_2(l):      Quadrat des Betrags des Drehimpulses 
#                zur Nebenquantenzahl l
#   nmexc(n,l):  Numerische Exzentrizität der Bahnellipse 
#                zur Hauptquantenzahl n und Nebenquantenzahl l
#   rad(t,n,l):  Radius der Elektronenbahn zum Winkel t 
#                bei Hauptquantenzahl n und Nebenquantenzahl l 
#
# (Alle Größen sind im MKS-System angegeben)
# **************************************************************************

reset

#Konstanten
h       = 6.62E-34
h_      = h/(2.0*pi)
e0      = 1.602E-19
me      = 9.10908E-31
eps0    = 8.8542E-12

#Abgeleitete Werte
mr      = me*1.00055
h_2     = h_ * h_
G       = e0*e0/(4.0*pi*eps0)
K       = mr * G

#Funktionen
enrg(n)      = -mr * (e0**4) / (32.0 * (pi**2) * (eps0**2) * h_2 * (n**2))
l_2(l)       = (l+1.) * (l+1.) * h_2
nmexz(n,l)   = 1 + 2.0 * enrg(n) * l_2(l)/ mr / (G**2)
rad(phi,n,l) = l_2(l)/K/(1.0 + sqrt(nmexz(n,l))*cos(pi-phi))

#Plotten
set output "bohr-sommerf.png"
set terminal png medium size 720,450 \
    xffffff x000000 x000000 \
    x008800 \
    xff8800 xff0000 \
    x00ffff x00aaff x0000ff \
    x000000
set clip points
unset border
set dummy t
set polar
set angles radians
set samples 320, 320
set xzeroaxis lt 0 lw 1.000
set yzeroaxis lt 0 lw 1.000
set xtics axis nomirror norotate autofreq
set ytics axis nomirror norotate autofreq
set title "" font ""
set trange [0.00000 : 2 * pi ] noreverse nowriteback

plot rad(t,1,0) lw 3 title "n=1, l=0", \
     rad(t,2,0) lw 3 title "n=2, l=0", rad(t,2,1) lw 3 title "n=2, l=1", \
     rad(t,3,0) lw 3 title "n=3, l=0", rad(t,3,1) lw 3 title "n=3, l=1", \
     rad(t,3,2) lw 3 title "n=3, l=2", 0.2*rad(t,1,0) lw 1 notitle with filledcurves closed

[Bearbeiten] Lizenz

Diese Datei wurde unter der GNU-Lizenz für freie Dokumentation veröffentlicht.

Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren. Es gibt keine unveränderlichen Abschnitte, keinen vorderen Umschlagtext und keinen hinteren Umschlagtext.

Dateiversionen

Legende: (Aktuell) = Dies ist die aktuelle Datei, (Löschen) = lösche diese alte Version, (Zurücksetzen) = verwende wieder diese alte Version.

(Löschen) (Aktuell) 02:18, 11. Jan. 2006 . . Dibe (Diskussion | Beiträge) . . 720 x 450 (8.231 Bytes) (Elektronenbahnen im Bohr-Sommerfeldschen-Atommodell. Bild wurde mit folgenden selbstgeschriebenen Programm erstellt. # ************************************************************************* # * # * ellipsen.gplot # * # * Programm zum Zeichnen von)