Image:Rhombic dodecahedron.jpg

From Wikipedia, the free encyclopedia

Image
File history
File links

No higher resolution available.

Rhombic_dodecahedron.jpg‎ (256 × 256 pixel, file size: 8 KB, MIME type: image/jpeg)

Rhombic dodecahedron, rendered in povray 3.5. See also Image:Rhombic_dodecahedra.jpg.

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts.
Subject to disclaimers.

1 Povray code

[edit] Povray code

The file was produced via the command "povray rhombic_dodecahedron.ini" on a Mac OS X machine with the fink installation of POV-Ray. The following three files are used. (GFDL applies to all)

[edit] File "rhombic_dodecahedron.povi"

#declare A=sqrt(2);
#declare R=0.025;

#declare rhombdod =
intersection {
    box { < -2, -2, -2>, <2,2,2> }
    plane { < 1, 1, 0>, A } 
    plane { < 1,-1, 0>, A }
    plane { <-1, 1, 0>, A }
    plane { <-1,-1, 0>, A }
    plane { < 1, 0, 1>, A }
    plane { < 1, 0,-1>, A }
    plane { <-1, 0, 1>, A }
    plane { <-1, 0,-1>, A }
    plane { < 0, 1, 1>, A }
    plane { < 0, 1,-1>, A }
    plane { < 0,-1, 1>, A }
    plane { < 0,-1,-1>, A }
    }

#declare tripod = 
    union{
        cylinder { <2,0,0>, <1,1,1>, R }
        cylinder { <0,2,0>, <1,1,1>, R }
        cylinder { <0,0,2>, <1,1,1>, R }
        sphere { <1,1,1>, R }
        }
#declare rhombdodedges =
    union {
        object { tripod }
        object { tripod rotate 90*z }
        object { tripod rotate 180*z }
        object { tripod rotate 270*z }
        object { tripod rotate 180*x }
        object { tripod rotate 180*x rotate 90*z }
        object { tripod rotate 180*x rotate 180*z }
        object { tripod rotate 180*x rotate 270*z }
        sphere { < 2, 0, 0 >, R }
        sphere { <-2, 0, 0 >, R }
        sphere { < 0, 2, 0 >, R }
        sphere { < 0,-2, 0 >, R }
        sphere { < 0, 0, 2 >, R }
        sphere { < 0, 0,-2 >, R }
        }

[edit] File "rhombic_dodecahedron.pov"

#include "colors.inc"
#include "rhombic_dodecahedron.povi"

global_settings{ ambient_light White }
background { color White }

#declare LX = 20;
#declare LZ = 50;
light_source { <LX,-LX,LZ> color White}
light_source { <-LX,LX,LZ> color White}
light_source { <LX,LX,LZ> color White}
light_source { <-LX,-LX,LZ> color White}

object { rhombdod
    texture {
        pigment { colour rgbt <1,1,0.4,0.3> }
        finish { ambient 0.1 diffuse 0.9 phong 1 }
        }
    }


object { rhombdodedges
    texture { pigment { colour Black } }
    }

camera {
    location 15*y
    direction -y
    right 0.3*x
    up 0.3*z
    rotate 10*x
    rotate 30*z
    }

[edit] File "rhombic_dodecahedron.ini"

Input_File_Name="rhombic_dodecahedron.pov"
Output_File_Type=N
Library_Path="/sw/share/povray-3.5/include/"
+v

+h256 +w256 Antialias=on

File history

Legend: (cur) = this is the current file, (del) = delete this old version, (rev) = revert to this old version.
Click on date to download the file or see the image uploaded on that date.